Scriptname _00E_MQ08Prologue_TealorFailsaveSC extends ObjectReference  
;This script fixes issues with MQ08Prologue as well as MQ10b scenes not playing properly due to Leora being absent (she never needed to be in the scene in MQ10b in the first place but was an actor in the scene therefore)
;=====================================================================================
;              							 EVENTS                  					 
;=====================================================================================

Event OnTriggerEnter(ObjectReference akActionRef)
	
	if akActionRef == PlayerREF
	
		If bDoItOnce == false
			If MQ08Prologue_SC1_Discussion == None
				MQ08Prologue_SC1_Discussion = Game.GetFormFromFile(0x0010D1A1, "Skyrim.esm") as Scene
			EndIf
			If MQ10b_SC2_Temple == None
				MQ10b_SC2_Temple = Game.GetFormFromFile(0x001080C3, "Skyrim.esm") as Scene
			EndIf
			If MQ10b == None
				MQ10b = Game.GetFormFromFile(0x001080B2, "Skyrim.esm") as Quest
			EndIf
			If MQ10bFunctions == None
				MQ10bFunctions = Game.GetFormFromFile(0x001080B2, "Skyrim.esm") as _00E_MQ10b_Questfunctions
			EndIf
			bDoItOnce = true
		EndIf
		
		If bDoItOnce2 == false ; Updated for golden sickle problems
			If MQ08PrologueFunctions == None
				MQ08PrologueFunctions = Game.GetFormFromFile(0x0010D19D, "Skyrim.esm") as _00E_MQ08aPrologue_Functions
			EndIf
			bDoItOnce2 = true
		EndIf

		if !MQ08Prologue_SC1_Discussion.IsPlaying() && (MQ08PrologueFunctions.GetCurrentStageID() >= 10 && MQ08PrologueFunctions.GetCurrentStageID() < 45)
			
			If MQ06_SC5_RitualScene.IsPlaying()
				MQ06_SC5_RitualScene.Stop()
			EndIf
			
			MQ08PrologueFunctions.SetUpScene(false)
		
		EndIf
	
		If !MQ10b_SC2_Temple.IsPlaying() && (MQ10b.GetCurrentStageID() >= 35 && MQ10b.GetCurrentStageID() < 70)
			MQ10bFunctions.SetUpTempleScene()
		EndIf

		If bMQ05Property == false && MQ05PrologueFunctions.GetCurrentStageID() == 5
			MQ05PrologueFunctions.FillTealorProperty()
			bMQ05Property = true
		EndIf
	EndIf
	
EndEvent

;=====================================================================================
;              							 PROPERTIES                  					 
;=====================================================================================

bool bDoItOnce
bool bDoItOnce2
bool bMQ05Property

Actor Property PlayerREF Auto
Quest Property MQ10b Auto

Scene Property MQ06_SC5_RitualScene Auto
Scene Property MQ08Prologue_SC1_Discussion Auto
Scene Property MQ10b_SC2_Temple Auto

_00E_MQ10b_Questfunctions Property MQ10bFunctions Auto

_00E_MQ08aPrologue_Functions Property MQ08PrologueFunctions Auto

_00E_MQ05Prologue_Functions Property MQ05PrologueFunctions Auto