Scriptname _00E_NQ29_Boss_BlindMinerSC extends Actor  

Event OnCombatStateChanged(Actor akTarget, Int aeCombatState)

	If aeCombatState == 1 
		If PlayerREF.GetItemCount(_00E_NQ29_Totem) > 0
			Self.GetActorBase().SetInvulnerable(False)
			bHasTotem = True
			MAGConjurePortalClose.Play(Self)
			_00E_EspionageFXS.Play(Self)
			_00E_NQ29_sBlindMinerTotemMSG.Show()
		EndIf
	ElseIf aeCombatState == 0
		MAGConjurePortalClose.Play(Self)
		_00E_EspionageFXS.Stop(Self)
		Self.GetActorBase().SetInvulnerable(True)
	EndIf
	
	
EndEvent

Event OnHit(ObjectReference akAggressor, Form akSource, Projectile akProjectile, bool abPowerAttack, bool abSneakAttack, bool abBashAttack, bool abHitBlocked)

	if !bHasTotem
		_00E_NQ29_sBlindMinerNoEffect.Show()
	EndIf

EndEvent

Event OnLoad()

	Self.RemoveSpell(AbDraugr)

EndEvent

Event OnDeath(Actor akKiller)

	if !NQ29.IsRunning()
		NQ29.SetCurrentStageID(5)
	Endif
	
	NQ29.SetObjectiveDisplayed(5)
	NQ29.SetObjectiveCompleted(5)
	_00E_EspionageFXS.Stop(Self)
	NQ29_MythicalCreaturesSlain.SetValue(NQ29_MythicalCreaturesSlain.GetValue() + 1)
	NQ29.UpdateCurrentInstanceGlobal(NQ29_MythicalCreaturesSlain)
	
	int CurrentCount = NQ29_MythicalCreaturesSlain.GetValueInt()

	if CurrentCount >= NQ29_MythicalCreaturesMax.GetValueInt()
		NQ29.SetObjectiveCompleted(0, 1)
		NQ29.SetCurrentStageID(10)
	Else
		NQ29.SetObjectiveCompleted(0,0)
		NQ29.SetObjectiveDisplayed(0, True, True)
	EndIf
	
EndEvent

bool bHasTotem

Message Property _00E_NQ29_sBlindMinerTotemMSG Auto
Message Property _00E_NQ29_sBlindMinerNoEffect Auto

MiscObject Property _00E_NQ29_Totem Auto
Actor Property PlayerREF Auto
Sound Property MAGConjurePortalClose Auto
EffectShader Property _00E_EspionageFXS Auto
GlobalVariable Property NQ29_MythicalCreaturesSlain Auto
GlobalVariable Property NQ29_MythicalCreaturesMax Auto

Spell Property AbDraugr Auto
Quest Property NQ29 Auto