Scriptname _00E_CQJ06_Functions extends Quest  

;=====================================================================================
;              							FUNCTIONS                    					 
;=====================================================================================

Function SetUp()

	If _00E_MC_JesparREF.IsDisabled()
		_00E_MC_JesparREF.Enable()
	EndIf
	
	_00E_MC_JesparREF.MoveTo(CQJ06_SC01_JesparMarker)

	CQJ06_SC01_JesparTavernSC.ForceStart()

EndFunction

Function EnableBand()

	CQJ06_SC01_Parent.Disable()
	CQJ06_SC01_PlayerBED.SetActorOwner(_00E_MC_JesparREF.GetActorOwner())
	CQJ06_SC01_TavernDoor.Lock(0)
	CQJ06_SC01_TavernDoor.SetOpen(True)
	SetObjectiveCompleted(5)
	CQC06.EnableBand()

EndFunction

Function CloseDoor()

	CQJ06_SC01_TavernDoor.SetOpen(False)

EndFunction

Function FadeOut()

	FadeToBlackImod.Apply()
	FadeToBlackHoldImod.ApplyCrossFade(afFadeDuration = 3.0)
	Utility.Wait(3)
	_00E_MC_JesparREF.UnequipAll()
	PlayerREF.UnequipAll()
	_00E_MC_JesparREF.MoveTo(CQJ06_SC01_BedREF)
	PlayerREF.MoveTo(CQJ06_SC01_Chair)
	_00E_QuestFunctions.PlayerAIWalk()
	CloseDoor()
	Game.ForceThirdPerson()
	SetStage(25)
	
EndFunction

Function GiveEPAndCleanUp()

	Levelsystem.GiveEP(__Config_iRewardEXP)
	If _00E_AchievementsEnabled.GetValueInt() == 1
		Steam.UnlockAchievement("END_ROMANCE_JESPAR_01")
	EndIf

EndFunction

Function FadeBackCleanUp()

	FadeToBlackBackImod.ApplyCrossFade()
	CQC06_SC01_EnableMarker.Enable()
	CQC06_SC01_MusicMarker.Disable()
	Utility.Wait(2)
	_00E_QuestFunctions.PlayerAiWalkStop()
	Game.EnablePlayerControls()
	
EndFunction

Function CleanUp()

	_00E_MC_JesparREF.SetOutfit(_00E_MC_JesparOutfit)
	
EndFunction

;=====================================================================================
;              							PROPERTIES                    					 
;=====================================================================================

int Property __Config_iRewardEXP = 500 Auto

_00E_QuestFunctions Property Levelsystem Auto

_00E_CQC06_Functions Property CQC06 Auto

Actor Property _00E_MC_JesparREF Auto
Actor Property PlayerREF Auto

ObjectReference Property CQJ06_SC01_JesparMarker Auto
ObjectReference Property CQJ06_SC01_PlayerBED Auto
ObjectReference Property CQJ06_SC01_Parent Auto
ObjectReference Property CQJ06_SC01_TavernDoor Auto
ObjectReference Property CQC06_SC01_EnableMarker Auto
ObjectReference Property CQC06_SC01_MusicMarker Auto
ObjectReference Property CQJ06_SC01_BedREF Auto
ObjectReference Property CQJ06_SC01_Chair Auto

Outfit Property _00E_MC_JesparOutfit Auto

Scene Property CQJ06_SC01_JesparTavernSC Auto

ImageSpaceModifier Property FadeToBlackImod Auto
ImageSpaceModifier Property FadeToBlackHoldImod Auto
ImageSpaceModifier Property FadeToBlackBackImod Auto

GlobalVariable Property _00E_AchievementsEnabled Auto