Scriptname _00E_FS_NQR01_Battle04_TransformSC extends Actor Conditional 

;=====================================================================================
;              							EVENTS                  					 
;=====================================================================================

Event OnUpdate()

	If Self.GetRace() == WerewolfRace || Self.GetRace() == WerewolfBeastRace
		Self.SetGhost(False)
	Else
		RegisterForSingleUpdate(2)
	EndIf

EndEvent

Event OnEnterBleedout()


	if !bTransformed

		bTransformed = True
		Utility.Wait(2)
		Self.SetGhost(True)
		Self.RestoreAV("Health", Self.GetBaseAV("Health"))
		Self.KnockAreaEffect(1, 1024)
		Self.PlaceAtMe(PowerRacialWoodElfCommandAnimalExplosion01) 
		Self.StopCombat()
		Self.StopCombatAlarm()
		Self.EvaluatePackage()
		Self.PlayIdle(IdleDrinkPotion)
		Utility.Wait(5)
		Self.SetGhost(False)
		AbWerewolf.Cast(Self, Self)
		WerewolfChange.Cast(Self, Self)
		Self.SetActorValue("Health", Self.GetBaseAV("Health")*fHealthMultiplicator)
		Self.SetActorValue("UnarmedDamage", iUnarmedDamage)
		Self.SetActorValue("DamageResist", iDamageResist)
		Self.GetActorBase().SetEssential(False)
		RegisterForSingleUpdate(5)
		bTransformedFinished = True
		Self.SetAV("Aggression", 3)
		Self.StartCombat(Game.GetPlayer())
		
	EndIf

EndEvent

;=====================================================================================
;              							PROPERTIES                  					 
;=====================================================================================

float fHealthMultiplicator = 2.0
int iUnarmedDamage = 40
int iDamageResist = 70

bool Property bTransformed Auto Hidden Conditional
bool Property bTransformedFinished Auto Hidden Conditional

Explosion Property PowerRacialWoodElfCommandAnimalExplosion01 Auto

Race Property WerewolfRace Auto
Race Property WerewolfBeastRace Auto

Spell Property AbWerewolf Auto
Spell Property WerewolfChange Auto

Idle Property IdleDrinkPotion Auto