Scriptname _00E_MQ04_SevfFireAct extends ObjectReference  

;=====================================================================================
;              							EVENTS                    					 
;=====================================================================================

Event OnHit(ObjectReference akAggressor, Form akSource, Projectile akProjectile, bool abPowerAttack, bool abSneakAttack, bool abBashAttack, bool abHitBlocked)

	If (akAggressor == PlayerREF)	&& (akSource == _00E_MQ04_FeuerloescherSpell) && (Done == False)
		Done = True
		_00E_MQ04_SavedSevf.SetValue(_00E_MQ04_SavedSevf.GetValueInt() + 1)
		_00E_MQ03FireISM.Apply()
		int Extinguish = FXFireOut.Play(PlayerREF)
		Sound.SetInstanceVolume(Extinguish, 3)
		objFireRef.Disable(True)
		objLightRef.Disable(True)
		Self.Disable(True)

		If (_00E_MQ04_SavedSevf.GetValueInt() == 3) && (_00E_MQ04_SevfDead.GetValueInt() == 0)
			MQ04.SetObjectiveCompleted(55)
			Utility.Wait(3)
			Sevf.GetActorReference().EvaluatePackage()
			MQ04_SC5_SevfEscapes.ForceStart()
		EndIf
	EndIf

EndEvent

;=====================================================================================
;              							PROPERTIES                    					 
;=====================================================================================

bool Done
ObjectReference Property objFireRef Auto
ObjectReference Property objLightRef Auto
Actor Property PlayerREF Auto
ReferenceAlias Property Sevf Auto
ImageSpaceModifier Property _00E_MQ03FireISM Auto
GlobalVariable Property _00E_MQ04_SavedSevf Auto
GlobalVariable Property _00E_MQ04_SevfDead Auto
Sound Property FXFireOut Auto
Spell Property _00E_MQ04_FeuerloescherSpell Auto
Quest Property MQ04 Auto
Scene Property MQ04_SC5_SevfEscapes Auto