Scriptname _00E_MQ07a_SoldierSC extends Actor  

Event OnLoad()
	If bDoneTeleporting == False
		bDoneTeleporting = True
		_00E_TeleportReappearShader.Play(self)
		Utility.Wait(0.1)
		SetAlpha(1.0)
		StartCombat(Game.GetPlayer())
	EndIf
EndEvent

Event OnDying(Actor akKiller)	
	UpdateEnemyWave()
EndEvent

Event OnDeath(Actor akKiller)
	UpdateEnemyWave()
EndEvent

Function UpdateEnemyWave()
	If bDone
		Return
	EndIf
	bDone = True

	GlobalVariable RefType
	
	Int iCurWave = MQ07a_CurrentWave.GetValueInt()
	If iCurWave == 1
		RefType = MQ07a_Wave_01_EnemiesTotal
	ElseIf iCurWave == 2
		RefType = MQ07a_Wave_02_EnemiesTotal
	ElseIf iCurWave == 3
		RefType = MQ07a_Wave_03_EnemiesTotal
	Else
		Return
	EndIf

	RefType.Mod(-1)
	(MQ07a as _00E_MQ07a_Functions).StartAmbushFailsave()

EndFunction

bool bDone
Bool bDoneTeleporting

GlobalVariable Property MQ07a_Wave_01_EnemiesTotal Auto
GlobalVariable Property MQ07a_Wave_02_EnemiesTotal Auto
GlobalVariable Property MQ07a_Wave_03_EnemiesTotal Auto

GlobalVariable Property MQ07a_CurrentWave Auto

Quest Property MQ07a Auto

EffectShader Property _00E_TeleportReappearShader Auto