Scriptname _00E_HealthBarSummons extends Actor
{Attaches and detaches the health bar to summons}

_00E_FS_ForgottenStories_Functions Property ForgottenStoriesMiscDialogue Auto
Bool Property DiesOnBleedout = False Auto

; Enderal SE: marked obsolete
Bool bRegisteredHealthBars = True ; Default to True, not False, for version update

Event OnLoad()
	ForgottenStoriesMiscDialogue.showActorHealthBars(self)
EndEvent

Event OnEnterBleedout()
	If DiesOnBleedout
		UnregisterHealthBars()
	EndIf
EndEvent

Event OnDying(Actor akKiller)
	UnregisterHealthBars()
EndEvent

Event OnDeath(Actor akKiller)
	UnregisterHealthBars() ; In case OnDying fails to unregister the health bars
EndEvent

Event OnUnload()
	UnregisterHealthBars() ; In case OnDying and OnDeath fail to unregister the health bars (see the essential oorbayas)
EndEvent

Function UnregisterHealthBars()
	ForgottenStoriesMiscDialogue.hideActorHealthBars(self)
EndFunction

Event OnCombatStateChanged(Actor akTarget, int aeCombatState)
	if aeCombatState == 1
		ForgottenStoriesMiscDialogue.showActorHealthBars(self)
	endif
endEvent

Event OnHit(ObjectReference akAggressor, Form akSource, Projectile akProjectile, Bool abPowerAttack, Bool abSneakAttack, Bool abBashAttack, Bool abHitBlocked)
	ForgottenStoriesMiscDialogue.showActorHealthBars(self)
endEvent