Scriptname _00E_NQ29_AshwidowSC extends ObjectReference  

Event OnUpdate()

	bResetTimer = False

EndEvent

Event OnCellAttach()
	If bDone
		; Failsafes and versions updates for pre-1.5.6.0 saves. Reset the widow and trigger if something went wrong during previous OnTriggerEnter
		Actor akAshWidow = NQ29.NQ29_Boss_AshWidow_REF
		If akAshWidow.IsEnabled() && akAshWidow.IsDead() == False
			bDone = False
			akAshWidow.Disable()
		EndIf
	EndIf
EndEvent

Event OnTriggerEnter(ObjectReference akActionRef)

	if akActionRef == PlayerREF && !bDone

		If PlayerREF.GetItemCount(_00E_NQ29_Boss_AshWidowClaw) >= 1

			if !NQ29.IsRunning()
				NQ29.SetCurrentStageID(5)
			EndIf

			NQ29.AshWidowSetWeather()
			NQ29.SpawnAshwidow()
			
			if NQ29.NQ29_Boss_AshWidow_REF.IsEnabled()
				bDone = True
			EndIf
			
		Elseif !bResetTimer
			bResetTimer = True
			_00E_A1_DevourSoulScreamM.Play(PlayerREF)
			_00E_NQ29_AshWidowMessage.Show()
			RegisterForSingleUpdate(120)
		EndIf
		
	EndIf

EndEvent

bool bResetTimer

bool bDone

Message Property _00E_NQ29_AshWidowMessage Auto
Sound Property _00E_A1_DevourSoulScreamM Auto

Actor Property PlayerREF Auto

_00E_NQ29_Functions Property NQ29 Auto

MiscObject Property _00E_NQ29_Boss_AshWidowClaw Auto