Scriptname _00E_Phasmalist_TrinketSC extends ObjectReference
; script on all phasmalist trinkets

_00E_Phasmalist_ApparationSC Property connectedApparation auto
_FS_Phasmalist_ControlQuest Property ControlQuest auto
int Property type auto ; what kind of apparition this one is, used to control arcane fever
{0 = Warrior, 1 = Archer, 2 = Mage, 3 = Hybrid}

Message Property chooseCombatStyle auto
FormList Property combatStyles auto

Bool hasAskedForCustomization = false
Int usedCombatStyle

Event OnContainerChanged(ObjectReference akNewContainer, ObjectReference akOldContainer)
	ControlQuest.forceInventoryContainerLoad(connectedApparation.inventoryContainer)
	If akNewContainer == Game.GetPlayer() && hasAskedForCustomization == False
		hasAskedForCustomization = True
		ControlQuest.OnPlayerTrinketCreated()
		ChooseApparitionCombatStyle()
	EndIf
EndEvent

Event OnEquipped(Actor akActor)
	ControlQuest.OnTrinketEquipped(Self)
EndEvent

Event OnUnequipped(Actor akActor)
	ControlQuest.OnTrinketUnequipped(Self)
EndEvent

Function ChooseApparitionCombatStyle()
	usedCombatStyle = chooseCombatStyle.show()
	ControlQuest.SetApparitionCombatStyle(GetUsedCombatStyle())
EndFunction

CombatStyle Function GetUsedCombatStyle()
	Return combatStyles.GetAt(usedCombatStyle) as CombatStyle
Endfunction