Scriptname _00E_MQP01_StartSC extends ObjectReference  

Event OnTriggerEnter (ObjectReference akActionREF)

	if akActionRef == PlayerREF && !bDone
		bDone = true
		Disable()
		If ! MQP01.IsCompleted() && MQ10a.GetCurrentStageID() != 5 && !MQ10a.IsRunning() && !MQ12c.IsRunning()
			if _00E_QuickStartPrompt.Show() > 0
				MQP01.CompleteAllObjectives()
				MQP01.CompleteQuest()
				MQP02.CompleteAllObjectives()
				MQP02.CompleteQuest()
				Utility.wait(0.5)
				If _00E_VideoSkip.GetValueInt() == 0 && EnderalFunctions.VideoSupport()
					Game.PlayBink("MQP03NearDeathExperience.bik", true)
				EndIf
				PlayerREF.MoveTo(_00E_ClassMenuOrigin)
				Debug.SendAnimationEvent(PlayerRef, "IdleForceDefaultState")
				Game.ShowRaceMenu()
				bool bDisableFighting = SKSE.GetVersion() > 0 && ! EnderalFunctions.IsVR()
				Game.DisablePlayerControls(false, bDisableFighting, true, false, true, false, false, true)
				MQP03.SetCurrentStageID(15)
				(MQP02 as _00E_MQP02_Functions).AddRacialAbilites()
			else
				MQP01.SetCurrentStageID(10)
			endif
		EndIf
	EndIf

EndEvent

bool bDone

Quest Property MQP01 Auto 
Quest Property MQP02 Auto  
Quest Property MQP03 Auto  
Quest Property MQ12c Auto 
Quest Property MQ10a Auto 

Actor Property PlayerREF Auto

Message Property _00E_QuickStartPrompt  Auto  

ObjectReference Property _00E_ClassMenuOrigin  Auto  

GlobalVariable Property _00E_VideoSkip Auto