Scriptname _00E_Func_CheckDependencies Hidden

Function CheckDependencies() global

	; SKSE is currently mandatory
	Int SKSEVer = SKSE.GetVersion()

	if SKSEVer == 0
		Utility.wait(2.0)
		Game.QuitToMainMenu()
		Debug.MessageBox("SKSE is not detected! Start Enderal through the launcher or skse64_loader.exe in the game directory.")
		Return
	endif

	; SkyUI is optional - override quest_journal.swf with the vanilla file, remove this check, and you are good to go
	Quest bSkyUI = Game.GetFormFromFile(0x802, "SkyUI_SE.esp") as Quest

	If bSkyUI == None
		Utility.wait(2.0)
		Game.QuitToMainMenu()
		Debug.MessageBox("SkyUI_SE.esp is not loaded! The game will not run properly. Open Data Files and enable it.")
		Return
	EndIf

	; To get rid of this, make alternatives for CreatePotion and CalculateContentStrength first
	if SKSE.GetPluginVersion("EnderalSE") == -1
		Utility.wait(2.0)
		Game.QuitToMainMenu()
		Debug.MessageBox("EnderalSE.dll is not loaded! The game will not run properly. Verify integrity of your files.\n\nThis may also happen, if your version of SKSE or Enderal is too old. In this case, it is advised to upgrade.")
		Return
	endif

	if (SKSE.GetPluginVersion("JContainers64") == -1) && (SKSE.GetPluginVersion("JContainersVR") == -1)
		; JContainers is only required for lycanthropy, so we just nag users without preventing playing without it
		Utility.wait(2.0)
		Debug.MessageBox("JContainers is not loaded! The game will not run properly. Verify integrity of your files or reinstall JContainers.")
	endif

EndFunction