Scriptname _00E_MQ12b_SC15_StartFailsaveSC extends ObjectReference  

; Failsave for http://forum.sureai.net//tracker.php?p=8&t=10674 .
; Sometimes, scene MQ12b_SC15_TempleScene03 would not properly start,
; even if MQ12b.GetCurrentStageID() was at 125 or 130. This script (placed
; on triggerbox _00E_MQ12b_SC15_StartFailsaveTGBX near the Beacon)
; would restart it in such cases.

Event OnTriggerEnter(ObjectReference akActionRef)

	if akActionRef == PlayerREF
		if MQ12b.GetCurrentStageID() == 125 || MQ12b.GetCurrentStageID() == 130
            if !MQ12b_SC15_TempleScene03.IsPlaying() && !MQ12b_SC15_TempleScene03.IsActionComplete(24)
                MQ12b.SetUpSC15()
            endif
		elseif MQ13a.GetCurrentStageID() == 5
            ; Another failsave, probably fixing a bug caused by the
            ; failsave above: Shoot down scene
            ; MQ12b_SC15_TempleScene03 if it's running past its time.
            if MQ12b_SC15_TempleScene03.IsPlaying()
                MQ13a.SetUp()
            endif
        endif
	endif
	
EndEvent

Actor Property PlayerREF Auto

_00E_MQ12b_Functions Property MQ12b Auto
_00E_MQ13a_Functions Property MQ13a Auto

Scene Property MQ12b_SC15_TempleScene03 Auto