Scriptname ETR_TrackNewItems extends ReferenceAlias

Actor Property PlayerRef Auto

FormList Property ETR_ItemsNew Auto
FormList Property ETR_ItemsFound Auto
FormList Property ETR_ItemsStored Auto
FormList Property ETR_ExcludeFromNew Auto
FormList Property ETR_PersistentStorageList Auto


event OnInit()

	if Game.GetModByName("HearthFires.esm") < 255 && Game.GetModByName("Enderal - Forgotten Stories.esm") == 255
		ETR_ExcludeFromNew.AddForm(Game.GetFormFromFile(0x807, "HearthFires.esm")) ; BYOHHouseCraftingCategorySmithing
	endif

	OnPlayerLoadGame()

endevent


event OnPlayerLoadGame()

	AddInventoryEventFilter(ETR_ItemsNew)

	if skse.GetPluginVersion("Ahzaab's moreHUD Plugin") >= 30800
		ahzmorehud.RegisterIconFormList("dbmNew", ETR_ItemsNew)
		ahzmorehud.RegisterIconFormList("dbmFound", ETR_ItemsFound)
		ahzmorehud.RegisterIconFormList("dbmDisp", ETR_ItemsStored)
	endif

	if skse.GetPluginVersion("Ahzaab's moreHUD Inventory Plugin") >= 10017
		ahzmorehudie.RegisterIconFormList("dbmNew", ETR_ItemsNew)
		ahzmorehudie.RegisterIconFormList("dbmFound", ETR_ItemsFound)
		ahzmorehudie.RegisterIconFormList("dbmDisp", ETR_ItemsStored)
	endif

	; Rebuild all lists to avoid discrepancies, stale data, and broken records

	ETR_ItemsStored.Revert()
	Eddoursul_Functions.AddItemsOfTypeAndKeywordToList(ETR_PersistentStorageList, ETR_ItemsStored, 26, None, ETR_ExcludeFromNew)
	Eddoursul_Functions.AddItemsOfTypeAndKeywordToList(ETR_PersistentStorageList, ETR_ItemsStored, 41, None, ETR_ExcludeFromNew)
	Eddoursul_Functions.AddItemsOfTypeAndKeywordToList(ETR_PersistentStorageList, ETR_ItemsStored, 27, None, ETR_ExcludeFromNew)
	Eddoursul_Functions.AddItemsOfTypeAndKeywordToList(ETR_PersistentStorageList, ETR_ItemsStored, 32, None, ETR_ExcludeFromNew)

	ETR_ItemsFound.Revert()
	Eddoursul_Functions.AddItemsOfTypeAndKeywordToList(PlayerRef, ETR_ItemsFound, 26, None, ETR_ExcludeFromNew, false, false, false)
	Eddoursul_Functions.AddItemsOfTypeAndKeywordToList(PlayerRef, ETR_ItemsFound, 41, None, ETR_ExcludeFromNew, false, false, false)
	Eddoursul_Functions.AddItemsOfTypeAndKeywordToList(PlayerRef, ETR_ItemsFound, 27, None, ETR_ExcludeFromNew, false, false, false)
	Eddoursul_Functions.AddItemsOfTypeAndKeywordToList(PlayerRef, ETR_ItemsFound, 32, None, ETR_ExcludeFromNew, false, false, false)

	Actor[] aFollowers = Eddoursul_Functions.GetPlayerFollowers()
	int i = aFollowers.length
	while i > 0
		i -= 1
		if ! aFollowers[i].IsDead() && ! aFollowers[i].IsDisabled()
			Eddoursul_Functions.AddItemsOfTypeAndKeywordToList(aFollowers[i], ETR_ItemsFound, 26, None, ETR_ExcludeFromNew, false, false, false)
			Eddoursul_Functions.AddItemsOfTypeAndKeywordToList(aFollowers[i], ETR_ItemsFound, 41, None, ETR_ExcludeFromNew, false, false, false)
			Eddoursul_Functions.AddItemsOfTypeAndKeywordToList(aFollowers[i], ETR_ItemsFound, 27, None, ETR_ExcludeFromNew, false, false, false)
			Eddoursul_Functions.AddItemsOfTypeAndKeywordToList(aFollowers[i], ETR_ItemsFound, 32, None, ETR_ExcludeFromNew, false, false, false)
		endif
	endwhile

	ETR_ItemsNew.Revert()
	Eddoursul_Functions.AddAllFormsToList(ETR_ItemsNew, 26, None, ETR_ExcludeFromNew) ; armor
	Eddoursul_Functions.AddAllFormsToList(ETR_ItemsNew, 41, None, ETR_ExcludeFromNew) ; weapons
	Eddoursul_Functions.AddAllFormsToList(ETR_ItemsNew, 27, None, ETR_ExcludeFromNew) ; books
	Eddoursul_Functions.AddAllFormsToList(ETR_ItemsNew, 32, None, ETR_ExcludeFromNew) ; misc items

endevent


event OnItemAdded(Form akBaseItem, int aiItemCount, ObjectReference akItemReference, ObjectReference akSourceContainer)

	ETR_ItemsNew.RemoveAddedForm(akBaseItem)
	ETR_ItemsFound.AddForm(akBaseItem)
	ETR_ItemsStored.RemoveAddedForm(akBaseItem)

	Debug.Notification("New artifact acquired: " + akBaseItem.GetName())

endevent