You can not select more than 25 topics
Topics must start with a letter or number, can include dashes ('-') and can be up to 35 characters long.
123 lines
4.4 KiB
123 lines
4.4 KiB
Scriptname ETR_TrackFoundItems extends ReferenceAlias
|
|
|
|
Actor Property PlayerRef Auto
|
|
|
|
FormList Property ETR_ItemsNew Auto
|
|
FormList Property ETR_ItemsFound Auto
|
|
FormList Property ETR_ItemsStored Auto
|
|
FormList Property ETR_PersistentStorageList Auto
|
|
FormList Property ETR_ExcludeFromNew Auto
|
|
|
|
Container Property ETR_CellStorageContainer Auto
|
|
|
|
Keyword Property LocTypePlayerHouse Auto
|
|
|
|
bool bAtHome = false
|
|
int iFollowerIndex = 0
|
|
|
|
|
|
event OnInit()
|
|
OnPlayerLoadGame()
|
|
endevent
|
|
|
|
|
|
Event OnPlayerLoadGame()
|
|
AddInventoryEventFilter(ETR_ItemsFound)
|
|
EndEvent
|
|
|
|
|
|
Event OnLocationChange(Location akOldLoc, Location akNewLoc)
|
|
bAtHome = akNewLoc && akNewLoc.HasKeyword(LocTypePlayerHouse)
|
|
RegisterForSingleUpdate(3.0) ; wait until followers load into the location
|
|
endEvent
|
|
|
|
|
|
Event OnUpdate()
|
|
|
|
;Debug.Notification("Follower index: " + iFollowerIndex)
|
|
|
|
int iCurrentFollowers = 0;
|
|
Actor[] aFollowers = Eddoursul_Functions.GetPlayerFollowers()
|
|
int i = aFollowers.length
|
|
while i > 0
|
|
i -= 1
|
|
if ! aFollowers[i].IsDead() && ! aFollowers[i].IsDisabled()
|
|
iCurrentFollowers += aFollowers[i].GetFormID()
|
|
;Debug.Notification("Follower ID: " + aFollowers[i].GetFormID())
|
|
endif
|
|
endwhile
|
|
|
|
;Debug.Notification("New follower index: " + iCurrentFollowers)
|
|
|
|
if iCurrentFollowers == iFollowerIndex
|
|
return
|
|
endif
|
|
|
|
; If the list of followers has changed, rebuild ETR_ItemsFound and ETR_ItemsNew
|
|
iFollowerIndex = iCurrentFollowers
|
|
|
|
Debug.Notification("Team changed, updating lists")
|
|
|
|
ETR_ItemsFound.Revert()
|
|
Eddoursul_Functions.AddItemsOfTypeAndKeywordToList(PlayerRef, ETR_ItemsFound, 26, None, ETR_ExcludeFromNew, false, false, false)
|
|
Eddoursul_Functions.AddItemsOfTypeAndKeywordToList(PlayerRef, ETR_ItemsFound, 41, None, ETR_ExcludeFromNew, false, false, false)
|
|
Eddoursul_Functions.AddItemsOfTypeAndKeywordToList(PlayerRef, ETR_ItemsFound, 27, None, ETR_ExcludeFromNew, false, false, false)
|
|
Eddoursul_Functions.AddItemsOfTypeAndKeywordToList(PlayerRef, ETR_ItemsFound, 32, None, ETR_ExcludeFromNew, false, false, false)
|
|
|
|
i = aFollowers.length
|
|
while i > 0
|
|
i -= 1
|
|
if ! aFollowers[i].IsDead() && ! aFollowers[i].IsDisabled()
|
|
Eddoursul_Functions.AddItemsOfTypeAndKeywordToList(aFollowers[i], ETR_ItemsFound, 26, None, ETR_ExcludeFromNew, false, false, false)
|
|
Eddoursul_Functions.AddItemsOfTypeAndKeywordToList(aFollowers[i], ETR_ItemsFound, 41, None, ETR_ExcludeFromNew, false, false, false)
|
|
Eddoursul_Functions.AddItemsOfTypeAndKeywordToList(aFollowers[i], ETR_ItemsFound, 27, None, ETR_ExcludeFromNew, false, false, false)
|
|
Eddoursul_Functions.AddItemsOfTypeAndKeywordToList(aFollowers[i], ETR_ItemsFound, 32, None, ETR_ExcludeFromNew, false, false, false)
|
|
endif
|
|
endwhile
|
|
|
|
ETR_ItemsNew.Revert()
|
|
Eddoursul_Functions.AddAllFormsToList(ETR_ItemsNew, 26, None, ETR_ExcludeFromNew) ; armor
|
|
Eddoursul_Functions.AddAllFormsToList(ETR_ItemsNew, 41, None, ETR_ExcludeFromNew) ; weapons
|
|
Eddoursul_Functions.AddAllFormsToList(ETR_ItemsNew, 27, None, ETR_ExcludeFromNew) ; books
|
|
Eddoursul_Functions.AddAllFormsToList(ETR_ItemsNew, 32, None, ETR_ExcludeFromNew) ; misc items
|
|
|
|
EndEvent
|
|
|
|
|
|
event OnItemRemoved(Form akBaseItem, int aiItemCount, ObjectReference akItemReference, ObjectReference akDestContainer)
|
|
|
|
if akDestContainer
|
|
if akDestContainer as Actor
|
|
if (akDestContainer as Actor).IsPlayerTeammate()
|
|
; Keep follower items marked as found
|
|
return
|
|
endif
|
|
elseif ETR_PersistentStorageList.HasForm(akDestContainer)
|
|
ETR_ItemsFound.RemoveAddedForm(akBaseItem)
|
|
ETR_ItemsStored.AddForm(akBaseItem)
|
|
return
|
|
elseif bAtHome && akDestContainer.GetParentCell() != PlayerRef.GetParentCell()
|
|
return
|
|
endif
|
|
endif
|
|
|
|
if bAtHome && (akDestContainer || Eddoursul_Functions.HasRefInCell(akBaseItem, None, true, ETR_PersistentStorageList))
|
|
|
|
ETR_ItemsFound.RemoveAddedForm(akBaseItem)
|
|
ETR_ItemsStored.AddForm(akBaseItem)
|
|
|
|
ObjectReference cellStorage = Eddoursul_Functions.GetCellStorage(PlayerRef, ETR_PersistentStorageList, ETR_CellStorageContainer)
|
|
|
|
if cellStorage.GetItemCount(akBaseItem) == 0
|
|
cellStorage.AddItem(akBaseItem, 1, true)
|
|
endif
|
|
|
|
elseif PlayerRef.GetItemCount(akBaseItem) == 0 && Eddoursul_Functions.GetItemCountInActors(Eddoursul_Functions.GetPlayerFollowers(), akBaseItem) == 0
|
|
|
|
ETR_ItemsFound.RemoveAddedForm(akBaseItem)
|
|
ETR_ItemsStored.RemoveAddedForm(akBaseItem)
|
|
ETR_ItemsNew.AddForm(akBaseItem)
|
|
|
|
endif
|
|
|
|
endevent
|
|
|