enderalse/source/scripts/_00e_showtutorialmessage.psc

Scriptname _00E_ShowTutorialMessage extends ObjectReference  

Event OnTriggerEnter(ObjectReference akActionRef)

	If akActionRef != PlayerREF
		Return
	EndIf

	If Done == False && ((_00E_DisableTutorials == None) || (_00E_DisableTutorials.GetValueInt() == 0))
		if !(__Config_MessageBox)
			Done = True
			Message.ResetHelpMessage(InputEventName)
			TutorialMessage.ShowAsHelpMessage(InputEventName, Duration, IntervalTime, HowManyTimesDisplayed)
		Else
			If __Config_ShowOnlyOnce
				Done = True
				TutorialMessage.Show()
			EndIf
		EndIf
	EndIf

	If Done && __Config_DisableWhenDone
		Disable()
	EndIf

EndEvent

bool Property __Config_MessageBox Auto
{If true, the message will be displayed in a messagebox rather than a floating tutorial message}

bool Property __Config_ShowOnlyOnce = True Auto

Bool Property __Config_DisableWhenDone = True Auto

bool Done
int Property Duration = 5 Auto ;How long should the message be displayed
int Property IntervalTime = 30 Auto ;How much time should elapse between showings of the message
int Property HowManyTimesDisplayed = 1 Auto ;How often should the message be displayed in total

Message Property TutorialMessage Auto 

Actor Property PlayerREF Auto

GlobalVariable Property _00E_DisableTutorials Auto 

String Property InputEventName Auto ; If available, specify and input event, such as "Jump" or "Attack". The message will disappear after sucessful execution of this event.