670 lines
19 KiB
Plaintext
670 lines
19 KiB
Plaintext
Scriptname _00E_MQ13b_Functions extends Quest Conditional
|
||
|
||
Import _00E_QuestFunctions
|
||
Import Utility
|
||
|
||
Event OnUpdate()
|
||
|
||
MQ13b_SC01_Arrival_01.ForceStart()
|
||
|
||
EndEvent
|
||
|
||
;=====================================================================================
|
||
; FUNCTIONS
|
||
;=====================================================================================
|
||
|
||
Function SetUpSC01()
|
||
|
||
Weather.ReleaseOverride()
|
||
Game.RequestAutoSave()
|
||
FadeToBlackHoldIMOD.Apply()
|
||
|
||
akLijam = _00E_MQ07a_YoungMageREF
|
||
akKurmai = _00E_SC_KurmaiREF
|
||
akYaela = _00E_MC_YaelaREF
|
||
RegisterForSingleUpdate(2)
|
||
Timescale.SetValue(0.1)
|
||
Levelsystem.SkipTimeToHour(7)
|
||
PlayerREF.MoveTo(MQ13b_SC01_PlayerMarker)
|
||
fYDifference = (MQ13b_StarshipREF002.GetPositionY()) - (MQ13b_SC01_StarshipPierMarker.GetPositionY())
|
||
|
||
_00E_MC_JesparREF.Enable()
|
||
_00E_MC_CaliaREF.Enable()
|
||
|
||
akLijam.Enable()
|
||
akYaela.Enable()
|
||
_00E_MC_CaliaREF.SetOutfit(_00E_MC_Calia_Outfit)
|
||
_00E_MC_JesparREF.SetOutfit(_00E_MC_JesparOutfit)
|
||
|
||
akYaela.MoveTo(MQ13b_SC01_YaelaMarker)
|
||
akLijam.MoveTo(MQ13b_SC01_LijamMarker)
|
||
akKurmai.MoveTo(MQ13b_SC01_KurmaiMarker)
|
||
String facegen = "bUseFaceGenPreprocessedHeads:General"
|
||
Utility.SetINIBool(facegen, False)
|
||
Game.GetPlayer().QueueNiNodeUpdate()
|
||
Utility.SetINIBool(facegen, True)
|
||
|
||
GetRomance()
|
||
|
||
SetStage(10)
|
||
|
||
MQ13b_StarshipREF002.TranslateToREF(MQ13b_SC01_StarshipPierMarker, 40.0)
|
||
MQ13b_Starship_SteamREF.TranslateToREF(MQ13b_Starship_TranslateSteamREF, 40.0)
|
||
MQ13b_Starship_SteamREF001.TranslateToREF(MQ13b_Starship_TranslateSteamREF001, 40.0)
|
||
|
||
EndFunction
|
||
|
||
Function PlayCreakSound()
|
||
|
||
iCreakSound = AMBShipCreakDeck2DLP.Play(MQ13b_StarshipREF002)
|
||
|
||
EndFunction
|
||
|
||
Function GetRomance()
|
||
|
||
If CaliaRomance.GetValueInt() == 1
|
||
akCompanionRomance = _00E_MC_CaliaREF
|
||
akCompanionNoRomance = _00E_MC_JesparREF
|
||
akCompanionRomance.MoveTo(MQ13b_SC01_CompanionMarker)
|
||
akCompanionNoRomance.MoveTo(MQ13b_SC01_Companion02Marker)
|
||
Elseif JesparRomance.GetValueInt() == 1
|
||
akCompanionRomance = _00E_MC_JesparREF
|
||
akCompanionNoRomance = _00E_MC_CaliaREF
|
||
akCompanionRomance.MoveTo(MQ13b_SC01_CompanionMarker)
|
||
akCompanionNoRomance.MoveTo(MQ13b_SC01_Companion02Marker)
|
||
Else
|
||
If SympathyJespar.GetValueInt() > SympathyCalia.GetValueInt()
|
||
bNoRomance = True
|
||
akCompanionRomance = _00E_MC_JesparREF
|
||
akCompanionNoRomance = _00E_MC_CaliaREF
|
||
Else
|
||
akCompanionRomance = _00E_MC_CaliaREF
|
||
akCompanionNoRomance = _00E_MC_JesparREF
|
||
Endif
|
||
akCompanionRomance.MoveTo(MQ13b_SC01_OptionalCompanionMarker)
|
||
akCompanionNoRomance.MoveTo(MQ13b_SC01_Companion02Marker)
|
||
EndIf
|
||
|
||
refAliasCompanionRomance.ForceRefTo(akCompanionRomance)
|
||
refAliasCompanionNoRomance.ForceRefTo(akCompanionNoRomance)
|
||
|
||
Return
|
||
|
||
EndFunction
|
||
|
||
Function FadeBack()
|
||
|
||
Wait(1)
|
||
FadeToBlackBackIMOD.ApplyCrossFade()
|
||
FadeToBlackHoldIMOD.Remove()
|
||
FadeToBlackBackIMOD.Apply()
|
||
|
||
EndFunction
|
||
|
||
Function CompanionRomanceFailsave()
|
||
|
||
if akCompanionRomance.GetDistance(PlayerREF) >= 500
|
||
akCompanionRomance.MoveTo(PlayerREF)
|
||
EndIf
|
||
|
||
EndFunction
|
||
|
||
Function KurmaiFailsave()
|
||
|
||
_00E_SC_KurmaiREF.MoveTo(MQ13b_SC03_KurmaiKneelMarker)
|
||
|
||
EndFunction
|
||
|
||
Function PlayerFailsave()
|
||
|
||
objPlayerMarker = PlayerREF.PlaceAtMe(XMarkerHeading)
|
||
objPlayerMarker.SetPosition(PlayerREF.GetPositionX(), (PlayerREF.GetPositionY() - fYDifference), PlayerREF.GetPositionZ())
|
||
PlayerREF.TranslateToREF(objPlayerMarker, 20.0, 1.0)
|
||
|
||
If !bNoRomance
|
||
objCompanionMarker = akCompanionRomance.PlaceAtMe(XMarkerHeading)
|
||
objCompanionMarker.SetPosition(akCompanionRomance.GetPositionX(), (akCompanionRomance.GetPositionY() - fYDifference), akCompanionRomance.GetPositionZ())
|
||
akCompanionRomance.TranslateToREF(objCompanionMarker, 20, 1.0)
|
||
EndIf
|
||
|
||
EndFunction
|
||
|
||
Function ShipArrive()
|
||
|
||
Sound.StopInstance(iCreakSound)
|
||
_00E_MQ07a_YoungMageREF.StopTranslation()
|
||
_00E_MC_YaelaREF.StopTranslation()
|
||
_00E_SC_KurmaiREF.StopTranslation()
|
||
akCompanionNoRomance.StopTranslation()
|
||
akCompanionRomance.StopTranslation()
|
||
|
||
EndFunction
|
||
|
||
Function StartSC02()
|
||
|
||
MQ13b_SC02_Arrival_02.ForceStart()
|
||
|
||
EndFunction
|
||
|
||
Function StartSC03()
|
||
|
||
SetObjectiveDisplayed(1)
|
||
MQ13b_SC03_WalkToCitadel.ForceStart()
|
||
|
||
EndFunction
|
||
|
||
Function AddExploreMusic()
|
||
|
||
_00E_Music_Explore_Unique_Starcity.Add()
|
||
|
||
EndFunction
|
||
|
||
Function CompanionFailsave()
|
||
|
||
; This triggers if the player has closed in on Kurmai, but the companions haven't yet. Useful when they get stuck in the package.
|
||
|
||
If akYaela.GetDistance(MQ13b_SC03_YaelaArrive) > 350
|
||
akYaela.MoveTo(MQ13b_SC03_DebugCompanionMarker)
|
||
akLijam.MoveTo(MQ13b_SC03_DebugCompanionMarker)
|
||
akCompanionRomance.MoveTo(MQ13b_SC03_DebugCompanionMarker)
|
||
akCompanionNoRomance.MoveTo(MQ13b_SC03_DebugCompanionMarker)
|
||
EndIf
|
||
|
||
EndFunction
|
||
|
||
Function StartSC04()
|
||
|
||
_00E_MC_YaelaREF.SetActorValue("speedMult", 70)
|
||
|
||
MQ13b_SC04_CitadelGate.ForceStart()
|
||
|
||
EndFunction
|
||
|
||
Function StartSC05()
|
||
|
||
_00E_MC_YaelaREF.SetActorValue("speedMult", 100)
|
||
MQ13b_SC05_SearchForSideEntrance.ForceStart()
|
||
|
||
EndFunction
|
||
|
||
Function StartSC06()
|
||
|
||
_00E_Music_Explore_Unique_Starcity.Remove()
|
||
FadeToBlackIMOD.Apply()
|
||
FadeToBlackHoldIMOD.ApplyCrossFade(2.5)
|
||
Wait(2.5)
|
||
akLijam.MoveTo(MQ13b_SC06_Lijam)
|
||
akKurmai.MoveTo(MQ13b_SC06_Kurmai)
|
||
akYaela.MoveTo(MQ13b_SC06_Yaela)
|
||
akCompanionRomance.MoveTo(MQ13b_SC06_Jespar)
|
||
akCompanionNoRomance.MoveTo(MQ13b_SC06_Calia)
|
||
PlayerREF.MoveTo(MQ13b_SC06_Player)
|
||
FadeToBlackBackIMOD.ApplyCrossFade(2)
|
||
MQ13b_SC06_ExpeditionPlanning.ForceStart()
|
||
|
||
EndFunction
|
||
|
||
Function StartSC07()
|
||
|
||
MQ13b_SC03_DoorREF.Lock(False)
|
||
akLijam.EvaluatePackage()
|
||
akCompanionNoRomance.EvaluatePackage()
|
||
|
||
_00E_QuestFunctions.SetNPCAsCompanion(_00E_MC_YaelaREF, True, 450, 200, 600)
|
||
_00E_QuestFunctions.SetNPCAsCompanion(_00E_SC_KurmaiREF, True, 250, 250, 250)
|
||
_00E_QuestFunctions.SetNPCAsCompanion(akCompanionRomance, True, 600, 700, 200)
|
||
|
||
MQ13b_SC07_NexusTower_01.ForceStart()
|
||
|
||
EndFunction
|
||
|
||
Function DisableKurmai()
|
||
|
||
akKurmai.MoveTo(MQ13b_SC07_KurmaiMoveMarker)
|
||
|
||
EndFunction
|
||
|
||
Function StartSC08()
|
||
|
||
_00E_QuestFunctions.SetNPCAsCompanion(_00E_MC_YaelaREF, False)
|
||
_00E_QuestFunctions.SetNPCAsCompanion(_00E_SC_KurmaiREF, False)
|
||
_00E_QuestFunctions.SetNPCAsCompanion(akCompanionRomance, False)
|
||
|
||
MQ13b_SC08_NexusTower_02.ForceStart()
|
||
|
||
EndFunction
|
||
|
||
Function SpawnCompanion()
|
||
|
||
akCompanionRomance.MoveTo(MQ13b_SC08_CompanionSpawn)
|
||
|
||
EndFunction
|
||
|
||
Function SpawnYaela()
|
||
|
||
akYaela.MoveTo(MQ13b_SC08_YaelaSpawn)
|
||
|
||
EndFunction
|
||
|
||
Function ShowFailedMessage(int iSpot)
|
||
|
||
if iSpot == 1
|
||
bSpot01Searched = True
|
||
_00E_MQ13b_SC08_Thought01.ShowAsHelpMessage("Thought01", 5, 5, 1)
|
||
Else
|
||
bSpot02Searched = True
|
||
_00E_MQ13b_SC08_Thought02.ShowAsHelpMessage("Thought02", 5, 5, 1)
|
||
EndIf
|
||
|
||
EndFunction
|
||
|
||
Function MoveElevator()
|
||
|
||
objElevatorOrigin = MQ13b_SC08_ElevatorREF.PlaceAtMe(XMarkerHeading)
|
||
MQ13b_SC08_ElevatorREF.TranslateToREF(MQ13b_SC08_ElevatorTranslateREF, 300.0)
|
||
StartElevatorSound()
|
||
|
||
EndFunction
|
||
|
||
Function StartElevatorSound()
|
||
|
||
DRSDwemerLiftOpenM.Play(MQ13b_SC08_ElevatorREF)
|
||
Wait(1)
|
||
iElevatorSound = OBJDwemerGearsMultipleLP.Play(MQ13b_SC08_ElevatorREF)
|
||
|
||
EndFunction
|
||
|
||
Function StopElevatorSound()
|
||
|
||
Sound.StopInstance(iElevatorSound)
|
||
DRSDwemerSmall01Open.Play(MQ13b_SC08_ElevatorREF)
|
||
|
||
EndFunction
|
||
|
||
Function MoveElevatorUP()
|
||
|
||
Game.DisablePlayerControls()
|
||
PlayerREF.TranslateTo(PlayerREF.GetPositionX(), PlayerREF.GetPositionY(), (PlayerREF.GetPositionZ() + 500.0), 0.0, 0.0, 0.0, 140.0)
|
||
akYaela.TranslateTo(akYaela.GetPositionX(), akYaela.GetPositionY(), (akYaela.GetPositionZ() + 500.0), 0.0, 0.0, 0.0, 140.0)
|
||
akCompanionRomance.TranslateTo(akCompanionRomance.GetPositionX(), akCompanionRomance.GetPositionY(), (akCompanionRomance.GetPositionZ() + 500.0), 0.0, 0.0, 0.0, 140.0)
|
||
MQ13b_SC08_ElevatorREF.TranslateToREF(objElevatorOrigin, 140.0)
|
||
StartElevatorSound()
|
||
Wait(1)
|
||
Debug.SetGodMode(False)
|
||
|
||
EndFunction
|
||
|
||
Function FadeOutAndSC09()
|
||
|
||
FadeToBlackIMOD.Apply()
|
||
Wait(2)
|
||
PlayerREF.MoveTo(MQ13b_SC09_PlayerStart)
|
||
akYaela.MoveTo(MQ13b_SC09_YaelaStart)
|
||
akCompanionRomance.MoveTo(MQ13b_SC09_CompanionStart)
|
||
StopElevatorSound()
|
||
Game.EnablePlayerControls()
|
||
MQ13b_SC09_NexusTower_03.ForceStart()
|
||
|
||
EndFunction
|
||
|
||
Function ActivateStairs()
|
||
|
||
MQ13b_SC09_HiddenStairs.PlayAnimation("down")
|
||
Levelsystem.SkipTimeToHour(8.75)
|
||
|
||
EndFunction
|
||
|
||
Function StartSC10()
|
||
|
||
_00E_SilenceAbruptHighPriority.Add()
|
||
akCompanionRomance.Enable()
|
||
akCompanionRomance.MoveTo(PlayerREF)
|
||
akYaela.Enable()
|
||
akYaela.MoveTo(PlayerREF)
|
||
Levelsystem.SkipTimeToHour(10.50)
|
||
|
||
MQ13b_SC10_NexusTower_04.ForceStart()
|
||
|
||
EndFunction
|
||
|
||
Function NexusElevatorDown()
|
||
|
||
akYaela.PlayIdle(activateDoor)
|
||
Wait(0.25)
|
||
QSTAstrolabeButtonPressX.Play(akYaela)
|
||
_00E_Music_Explore_Unique_Starcity.Remove()
|
||
Wait(0.25)
|
||
|
||
if akCompanionRomance == _00E_MC_JesparREF
|
||
_00E_MQ14_SC10_JepsarUphN.Play(akCompanionRomance)
|
||
Else
|
||
_00E_MQ14_SC10_CaliaUphN.Play(akCompanionRomance)
|
||
EndIf
|
||
|
||
_00E_MQ13b_SC10_NexusFade.Apply()
|
||
MQ13b_SC10_StarlingReliefREF002.SetPosition(1569.0, 8791.0, 20378.0)
|
||
MQ13b_SC10_StarlingReliefREF002.SetAngle(0, 0, 326.2419)
|
||
MQ13b_SC10_Relief_Shaft_01.SetPosition(1567.6582, 8788.8955, 21431.4785)
|
||
MQ13b_SC10_ReliefTranslateToMarker.SetPosition(1545.6665, 8771.6738, 21343.3164)
|
||
MQ13b_SC10_Relief_Shaft_01.SetAngle(0, 0, 270.0000)
|
||
MQ13b_SC10_ReliefTranslateToMarker.SetAngle(0, 0, 326.2419)
|
||
MQ13b_SC09_PlayerTranslateMarker = PlayerREF.PlaceAtMe(XMarkerHeading)
|
||
MQ13b_SC09_PlayerTranslateMarker.SetPosition(PlayerREF.GetPositionX(), PlayerREF.GetPositionY(), 19873.0430)
|
||
MQ13b_SC10_NexusLift002.TranslateToRef(MQ13b_SC10_TranslateMarker008, 600)
|
||
PlayerREF.TranslateToREF(MQ13b_SC09_PlayerTranslateMarker, 600)
|
||
MQ13b_SC10_NexusLift002.PlaceAtMe(FXdustDropMedExplosion)
|
||
iNexusLiftSound = DRSStoneRotatingDiscLPM.Play(MQ13b_SC10_NexusLift002)
|
||
bNexusLiftInMotion = True
|
||
MQ13b_SC10_NexusLift002.KnockAreaEffect(1, 1024)
|
||
akCompanionRomance.SetGhost(False)
|
||
akYaela.SetGhost(False)
|
||
akYaela.SetNoBleedoutRecovery(True)
|
||
akCompanionRomance.SetNoBleedoutRecovery(True)
|
||
akYaela.DamageActorValue("Health", 1000)
|
||
akCompanionRomance.DamageActorValue("Health", 1000)
|
||
MQ13b_SC11_ShutterREF.Enable()
|
||
MQ13b_SC11_ShutterREF.TranslateToRef(MQ13b_SC11_ShutterREFMarker, 300.0, 300.0)
|
||
Timescale.SetValue(10000)
|
||
Game.DisablePlayerControls()
|
||
Debug.SetGodMode(1)
|
||
Game.ForceFirstPerson()
|
||
Game.ShakeCamera(afStrength = 0.5, afDuration = 10)
|
||
int iTimer = 1
|
||
|
||
While bNexusLiftInMotion && (GameHour.GetValue() <= 20)
|
||
MQ13b_SC10_NexusLift002.PlaceAtMe(FXdustDropMedExplosion)
|
||
iTimer -= 1
|
||
|
||
if GameHour.GetValue() >= 20
|
||
Timescale.SetValue(0.1)
|
||
EndIf
|
||
|
||
if iTimer == 0
|
||
_00E_MQ13b_SC10_NexusFade.ApplyCrossFade(0.5)
|
||
EndIf
|
||
|
||
Wait(0.5)
|
||
|
||
EndWhile
|
||
|
||
Timescale.SetValue(0.1)
|
||
|
||
EndFunction
|
||
|
||
Function NexusElevatorStop()
|
||
|
||
akYaela.StopTranslation()
|
||
akCompanionRomance.StopTranslation()
|
||
PlayerREF.StopTranslation()
|
||
MQ13b_SC11_ShutterREF.MoveTo(MQ13b_SC11_ShutterREFMarker)
|
||
MQ13b_SC10_NexusLift002.TranslateToRef(MQ13b_SC10_TranslateMarker007, 600)
|
||
MQ13b_SC10_NexusLift002.PlaceAtMe(FXdustDropMedExplosion)
|
||
akYaela.SetGhost(True)
|
||
akCompanionRomance.SetGhost(True)
|
||
_00E_MQ13b_SC10_NexusFade.Apply()
|
||
akYaela.SetNoBleedoutRecovery(False)
|
||
akCompanionRomance.SetNoBleedoutRecovery(False)
|
||
akYaela.RestoreAV("Health", 1000)
|
||
akCompanionRomance.RestoreAV("Health", 1000)
|
||
MQ13b_SC10_ImpactMarker002.PlayImpactEffect(FXDragonLandingImpactSet)
|
||
Sound.StopInstance(iNexusLiftSound)
|
||
Game.ShakeCamera(afStrength = 1)
|
||
Game.EnablePlayerControls()
|
||
_00E_MQ13b_SC10_NexusFadeHOLD.Apply()
|
||
PlayerAIWalkStop()
|
||
PlayerREF.SetGhost(False)
|
||
|
||
_00E_StaggerSelf.Cast(PlayerREF)
|
||
bNexusLiftInMotion = False
|
||
|
||
EndFunction
|
||
|
||
Function BeginRotation()
|
||
|
||
Wait(2)
|
||
|
||
bReliefRotating = True
|
||
|
||
float fReliefX = MQ13b_SC10_StarlingReliefREF002.GetPositionX()
|
||
float fReliefY = MQ13b_SC10_StarlingReliefREF002.GetPositionY()
|
||
float fReliefZ = MQ13b_SC10_StarlingReliefREF002.GetPositionZ()
|
||
|
||
float fReliefAngleX = 0
|
||
float fReliefAngleY = 0
|
||
float fReliefAngleZ = MQ13b_SC10_StarlingReliefREF002.GetAngleZ()
|
||
|
||
DRSStoneMagicLabyrinthianOpenM.Play(MQ13b_SC10_StarlingReliefREF002)
|
||
Wait(1)
|
||
iReliefRotationSound = DRSStoneRotatingDiscLPM.Play(MQ13b_SC10_StarlingReliefREF002)
|
||
akYaela.EquipItem(Torch01Intense, true, true)
|
||
MQ13b_SC10_StarlingReliefREF002.StartRotationLoop()
|
||
|
||
EndFunction
|
||
|
||
Function StopRotation()
|
||
|
||
Sound.StopInstance(iReliefRotationSound)
|
||
bReliefRotating = False
|
||
|
||
EndFunction
|
||
|
||
Function D05_CompanionFailsave()
|
||
|
||
; Failsave to ensure that the player's companion gets moved to
|
||
; the bottom of the nexus elevator (i.e., where the old reliefs
|
||
; are) if he/she isn't already there.
|
||
|
||
if akCompanionRomance.GetDistance(akYaela) > 1000
|
||
akCompanionRomance.MoveTo(MQ13b_SC09_CompPitMarker015)
|
||
endif
|
||
|
||
EndFunction
|
||
|
||
Function StartSC11()
|
||
|
||
PlayerREF.AddItem(Torch01Intense, 1)
|
||
PlayerREF.EquipItem(Torch01Intense)
|
||
SetObjectiveDisplayed(20)
|
||
|
||
MQ13b_SC11_PictureLinker002.Enable()
|
||
Levelsystem.RemoveSilence()
|
||
_00E_Music_Special_Zyklus_Loop.Add()
|
||
|
||
MQ13b_SC11_NexusTower_05.ForceStart()
|
||
|
||
EndFunction
|
||
|
||
Function YaelaUnequipTorch()
|
||
|
||
_00E_Music_Special_Zyklus_Loop.Remove()
|
||
_00E_SilenceAbruptHighPriority.Add()
|
||
akYaela.UnequipItem(Torch01Intense, true, true)
|
||
Debug.SendAnimationEvent(akYaela, "IdleForceDefaultState")
|
||
|
||
EndFunction
|
||
|
||
Function SayLine(int iExplanationLine)
|
||
|
||
If iExplanationLine != 4
|
||
iExplanationLineController = iExplanationLine
|
||
akYaela.Say(MQ13b_D0_ExplanationTopicView)
|
||
Else
|
||
akCompanionRomance.Say(MQ13b_D0_ExplanationTopicView)
|
||
EndIf
|
||
|
||
|
||
EndFunction
|
||
|
||
Function UpdateReliefCounter()
|
||
|
||
iReliefCounter += 1
|
||
bCurrentlySpeaking = False
|
||
|
||
EndFunction
|
||
|
||
Function FinishUpAndStartMQ13c()
|
||
|
||
Levelsystem.GiveEP(__Config_RewardEXP)
|
||
MQ13c.SetStage(5)
|
||
|
||
EndFunction
|
||
|
||
;=====================================================================================
|
||
; PROPERTY
|
||
;=====================================================================================
|
||
|
||
; TIMESCALE ZUR<55>CKSETZEN! ; MUSIC-Types REMOVEN! ; GOD MODE RUNTERSETZEN!
|
||
|
||
int Property __Config_RewardEXP = 500 Auto
|
||
|
||
_00E_QuestFunctions Property Levelsystem Auto
|
||
|
||
bool Property bSpot01Searched Auto Conditional Hidden
|
||
bool Property bSpot02Searched Auto Conditional Hidden
|
||
bool Property bNexusLiftInMotion Auto Conditional Hidden
|
||
bool Property bReliefRotating = True Auto Conditional Hidden
|
||
bool Property bCurrentlySpeaking Auto Conditional Hidden
|
||
bool Property bShipArrived Auto Conditional Hidden
|
||
|
||
int Property iExplanationLineController Auto Conditional Hidden
|
||
int Property iReliefCounter Auto Conditional Hidden
|
||
|
||
float fYDifference
|
||
|
||
int iCreakSound
|
||
int iElevatorSound
|
||
int iNexusLiftSound
|
||
int iReliefRotationSound
|
||
|
||
bool bNoRomance
|
||
|
||
Actor Property akCompanionRomance Auto Hidden
|
||
Actor Property akCompanionNoRomance Auto Hidden
|
||
|
||
Actor akLijam
|
||
Actor akYaela
|
||
Actor akKurmai
|
||
|
||
ObjectReference objPlayerMarker
|
||
ObjectReference objCompanionMarker
|
||
ObjectReference objElevatorOrigin
|
||
ObjectReference objYaelaPitMarker
|
||
ObjectReference objCompanionPitMarker
|
||
|
||
Actor Property PlayerREF Auto
|
||
Actor Property _00E_MC_JesparREF Auto
|
||
Actor Property _00E_MC_CaliaREF Auto
|
||
Actor Property _00E_SC_KurmaiREF Auto
|
||
Actor Property _00E_MC_YaelaREF Auto
|
||
Actor Property _00E_MQ07a_YoungMageREF Auto
|
||
|
||
Quest Property MQ13c Auto
|
||
|
||
ImpactDataSet Property FXDragonLandingImpactSet Auto
|
||
|
||
MusicType Property _00E_Music_Explore_Unique_Starcity Auto
|
||
MusicType Property _00E_Music_Special_Zyklus_Loop Auto
|
||
MusicType Property _00E_SilenceAbruptHighPriority Auto
|
||
|
||
Explosion Property FXdustDropMedExplosion Auto
|
||
|
||
Light Property Torch01Intense Auto
|
||
|
||
Spell Property _00E_StaggerSelf Auto
|
||
|
||
Static Property XMarkerHeading Auto
|
||
|
||
Sound Property AMBShipCreakDeck2DLP Auto
|
||
Sound Property OBJDwemerGearsMultipleLP Auto
|
||
Sound Property DRSDwemerLiftOpenM Auto
|
||
Sound Property DRSDwemerSmall01Open Auto
|
||
Sound Property DRSStoneRotatingDiscLPM Auto
|
||
Sound Property DRSStoneMagicLabyrinthianOpenM Auto
|
||
Sound Property QSTAstrolabeButtonPressX Auto
|
||
Sound Property _00E_MQ14_SC10_JepsarUphN Auto
|
||
Sound Property _00E_MQ14_SC10_CaliaUphN Auto
|
||
|
||
Message Property _00E_MQ13b_SC08_Thought01 Auto
|
||
Message Property _00E_MQ13b_SC08_Thought02 Auto
|
||
|
||
ReferenceAlias Property refAliasCompanionRomance Auto
|
||
ReferenceAlias Property refAliasCompanionNoRomance Auto
|
||
|
||
_00E_MQ13b_SC01_StarshipSC Property MQ13b_StarshipREF002 Auto
|
||
|
||
ObjectReference Property MQ13b_SC01_PlayerMarker Auto
|
||
ObjectReference Property MQ13b_SC01_StarshipPierMarker Auto
|
||
ObjectReference Property MQ13b_SC01_KurmaiMarker Auto
|
||
ObjectReference Property MQ13b_SC01_CompanionMarker Auto
|
||
ObjectReference Property MQ13b_SC01_LijamMarker Auto
|
||
ObjectReference Property MQ13b_SC01_Companion02Marker Auto
|
||
ObjectReference Property MQ13b_SC01_YaelaMarker Auto
|
||
ObjectReference Property MQ13b_SC01_OptionalCompanionMarker Auto
|
||
ObjectReference Property MQ13b_SC03_KurmaiKneelMarker Auto
|
||
ObjectReference Property MQ13b_SC03_YaelaArrive Auto
|
||
ObjectReference Property MQ13b_SC06_Lijam Auto
|
||
ObjectReference Property MQ13b_SC06_Yaela Auto
|
||
ObjectReference Property MQ13b_SC07_KurmaiMoveMarker Auto
|
||
ObjectReference Property MQ13b_SC08_CompanionSpawn Auto
|
||
ObjectReference Property MQ13b_SC08_YaelaSpawn Auto
|
||
ObjectReference Property MQ13b_SC08_ElevatorREF Auto
|
||
ObjectReference Property MQ13b_SC08_ElevatorTranslateREF Auto
|
||
ObjectReference Property MQ13b_SC09_YaelaStart Auto
|
||
ObjectReference Property MQ13b_SC09_CompanionStart Auto
|
||
ObjectReference Property MQ13b_SC09_PlayerStart Auto
|
||
ObjectReference Property MQ13b_SC09_HiddenStairs Auto
|
||
ObjectReference Property MQ13b_SC10_NexusLift002 Auto
|
||
ObjectReference Property MQ13b_SC10_TranslateMarker007 Auto
|
||
ObjectReference Property MQ13b_SC10_TranslateMarker008 Auto
|
||
_00E_MQ13b_SC10_ReliefRotationSC Property MQ13b_SC10_StarlingReliefREF002 Auto
|
||
ObjectReference Property MQ13b_SC10_ImpactMarker002 Auto
|
||
ObjectReference Property MQ13b_SC09_CompPitMarker015 Auto
|
||
ObjectReference Property MQ13b_SC11_PictureLinker002 Auto
|
||
ObjectReference Property MQ13b_SC03_DebugCompanionMarker Auto
|
||
ObjectReference Property MQ13b_SC03_DoorREF Auto
|
||
ObjectReference Property MQ13b_SC11_ShutterREF Auto
|
||
ObjectReference Property MQ13b_SC11_ShutterREFMarker Auto
|
||
_00E_MQ13b_SC10_ShaftSC Property MQ13b_SC10_Relief_Shaft_01 Auto
|
||
ObjectReference Property MQ13b_SC09_PlayerTranslateMarker Auto Hidden
|
||
ObjectReference Property MQ13b_SC10_ReliefTranslateToMarker Auto Hidden
|
||
ObjectReference Property MQ13b_Starship_SteamREF Auto
|
||
ObjectReference Property MQ13b_Starship_SteamREF001 Auto
|
||
ObjectReference Property MQ13b_Starship_TranslateSteamREF Auto
|
||
ObjectReference Property MQ13b_Starship_TranslateSteamREF001 Auto
|
||
|
||
Topic Property MQ13b_D0_ExplanationTopicView Auto
|
||
|
||
ObjectReference Property MQ13b_SC06_Jespar Auto
|
||
ObjectReference Property MQ13b_SC06_Calia Auto
|
||
ObjectReference Property MQ13b_SC06_Player Auto
|
||
ObjectReference Property MQ13b_SC06_Kurmai Auto
|
||
|
||
ImageSpaceModifier Property FadeToBlackIMOD Auto
|
||
ImageSpaceModifier Property FadeToBlackHoldIMOD Auto
|
||
ImageSpaceModifier Property FadeToBlackBackIMOD Auto
|
||
ImageSpaceModifier Property _00E_MQ13b_SC10_NexusFade Auto
|
||
ImageSpaceModifier Property _00E_MQ13b_SC10_NexusFadeHold Auto
|
||
|
||
Idle Property activateDoor Auto
|
||
|
||
Outfit Property _00E_MC_JesparOutfit Auto
|
||
Outfit Property _00E_MC_Calia_Outfit Auto
|
||
|
||
GlobalVariable Property CaliaRomance Auto
|
||
GlobalVariable Property JesparRomance Auto
|
||
GlobalVariable Property GameHour Auto
|
||
GlobalVariable Property Timescale Auto
|
||
GlobalVariable Property SympathyJespar Auto
|
||
GlobalVariable Property SympathyCalia Auto
|
||
|
||
Scene Property MQ13b_SC01_Arrival_01 Auto
|
||
Scene Property MQ13b_SC02_Arrival_02 Auto
|
||
Scene Property MQ13b_SC03_WalkToCitadel Auto
|
||
Scene Property MQ13b_SC04_CitadelGate Auto
|
||
Scene Property MQ13b_SC05_SearchForSideEntrance Auto
|
||
Scene Property MQ13b_SC06_ExpeditionPlanning Auto
|
||
Scene Property MQ13b_SC07_NexusTower_01 Auto
|
||
Scene Property MQ13b_SC08_NexusTower_02 Auto
|
||
Scene Property MQ13b_SC09_NexusTower_03 Auto
|
||
Scene Property MQ13b_SC10_NexusTower_04 Auto
|
||
Scene Property MQ13b_SC11_NexusTower_05 Auto |