enderalse/source/scripts/_00e_playerhousing_cellnamesc.psc

Scriptname _00E_PlayerHousing_CellNameSC extends ReferenceAlias 
{controls the names of the player houses, and the name of the rhalata temple}

;=====================================================================================
;              							EVENTS                  					 
;=====================================================================================

Event OnPlayerLoadGame()
	; Not calling TextInputEnabled() in case renames were made with keyboard earlier
	if ! SKSE.GetVersion()
		return
	endif

	If sHouseNobleQuarterName != ""
		CapitalCityPlayerHouseUpper.SetName(sHouseNobleQuarterName)
	Else
		if CapitalCityPlayerHouseUpper.GetActorOwner() == (GetReference() as Actor).GetActorBase()
			CapitalCityPlayerHouseUpper.SetName(_00E_sPlayerHouseNobleQuarterName.GetName())
		EndIf
	EndIf
	
	If sHouseMarketQuarterName != ""
		CapitalCityPlayerhouse.SetName(sHouseMarketQuarterName)
	Else
		If CapitalCityPlayerhouse.GetActorOwner() == (GetReference() as Actor).GetActorBase()
			CapitalCityPlayerhouse.SetName(_00E_sPlayerHouseMarketQuarterName.GetName())
		EndIf
	EndIf
	
	If FS_NQR03.GetCurrentStageID() >= 35
		FS_NQR03_RhalataTemple.SetName(_00E_sRhalataTempleName.GetName())
	EndIf
EndEvent


;=====================================================================================
;              							PROPERTIES                  					 
;=====================================================================================

string Property sHouseMarketQuarterName Auto
string Property sHouseNobleQuarterName Auto

Message Property _00E_sPlayerHouseMarketQuarterName Auto
Message Property _00E_sPlayerHouseNobleQuarterName Auto
Message Property _00E_sRhalataTempleName Auto

Cell Property CapitalCityPlayerHouseUpper Auto
Cell Property CapitalCityPlayerhouse Auto
Cell Property FS_NQR03_RhalataTemple Auto
Quest Property FS_NQR03 Auto