enderalse/source/scripts/_00e_gui_actorhealthbar.psc

Scriptname _00E_GUI_ActorHealthBar extends ski_widgetbase  

float _scale = 1.0
int _maxEntries = 5
float _fadeInDuration = 250.0
float _fadeOutDuration = 750.0
float _moveDuration = 1000.0
float _removeDuration = 15000.0
Form[] _currentlyDisplayedActors

int function _GetScriptVersion() Global
    return 1
endFunction

string function GetWidgetSource()
	return "skyui/companionpanel.swf"
endFunction

string function GetWidgetType()
	return "EFFPanel"
endFunction

int function GetVersion()
	return 1
endFunction

float property Scale
	float function get()
		return _scale
	endFunction
	
	function set(float a_val)
		_scale = a_val
		if (Ready)
			UpdateWidgetScale()
		endIf
	endFunction
endProperty

int Property MaxEntries
	int function get()
		return _maxEntries
	endFunction
	
	function set(int a_val)
		_maxEntries = a_val
		if (Ready)
			UpdateMaxEntries()
		endIf
	endFunction
endProperty

float property FadeInDuration
	float function get()
		return _fadeInDuration
	endFunction
	
	function set(float a_val)
		_fadeInDuration = a_val
		if (Ready)
			UpdateFadeInDuration()
		endIf
	endFunction
endProperty

float property FadeOutDuration
	float function get()
		return _fadeOutDuration
	endFunction
	
	function set(float a_val)
		_fadeOutDuration = a_val
		if (Ready)
			UpdateFadeOutDuration()
		endIf
	endFunction
endProperty

float property MoveDuration
	float function get()
		return _moveDuration
	endFunction
	
	function set(float a_val)
		_moveDuration = a_val
		if (Ready)
			UpdateMoveDuration()
		endIf
	endFunction
endProperty

float property RemoveDuration
	float function get()
		return _removeDuration
	endFunction
	
	function set(float a_val)
		_removeDuration = a_val
		if (Ready)
			UpdateRemoveDuration()
		endIf
	endFunction
endProperty

; @override SKI_WidgetBase
event OnWidgetReset()
	parent.OnWidgetReset()
	UpdateWidgetScale()
	UpdateMaxEntries()
	UpdateFadeInDuration()
	UpdateFadeOutDuration()
	UpdateMoveDuration()
	UpdateRemoveDuration()
endEvent

event OnGameReload()

	if SKSE.GetVersion() == 0
		Debug.Trace("NO SKSE: companion health bars are disabled")
		return
	endif

	parent.OnGameReload()

	If Game.GetModByName("SkyUI_SE.esp") == 255 || _00E_ActorHealthBarsEnabled.GetValue() == 0
		return
	endif

	RegisterEvents()

	Utility.Wait(FadeOutDuration / 1000.0 + 1.0)
	
	int i = _currentlyDisplayedActors.Length
	While i > 0
		i -= 1
		Actor akActor = _currentlyDisplayedActors[i] as Actor
		If ! akActor || akActor.GetFormID() == 0 || akActor.IsDeleted() || akActor.IsDisabled() || ! akActor.IsInCombat()
			_currentlyDisplayedActors[i] = None
		else
			AddActorRaw(akActor)
		EndIf
	EndWhile

	Actor[] aFollowers = EnderalFunctions.GetPlayerFollowers()
	i = aFollowers.length
	while i > 0
		i -= 1
		if aFollowers[i] && _currentlyDisplayedActors.find(aFollowers[i]) < 0
			AddActors(aFollowers[i])
		endif
	endwhile
	
Endevent

function RegisterEvents()

	if _currentlyDisplayedActors.length == 0
		_currentlyDisplayedActors = new Form[4]
	endif
	
	UI.Invoke(HUD_MENU, WidgetRoot + ".removeAllActors")
	RegisterForModEvent("Enderal_ShowActorHealth", "AddActors")
	RegisterForModEvent("Enderal_HideActorHealth", "RemoveActors")
	
endfunction

function UnregisterEvents()
	UI.Invoke(HUD_MENU, WidgetRoot + ".removeAllActors")
	UnregisterForModEvent("Enderal_ShowActorHealth")
	UnregisterForModEvent("Enderal_HideActorHealth")
endfunction

Function UpdateWidgetScale()
	UI.InvokeFloat(HUD_MENU, WidgetRoot + ".setScale", _scale * 100.0)
EndFunction

Function UpdateMaxEntries()
	UI.InvokeInt(HUD_MENU, WidgetRoot + ".setEntryCount", _maxEntries)
EndFunction

Function UpdateFadeInDuration()
	UI.InvokeFloat(HUD_MENU, WidgetRoot + ".setFadeInDuration", _fadeInDuration / 1000.0)
EndFunction

Function UpdateFadeOutDuration()
	UI.InvokeFloat(HUD_MENU, WidgetRoot + ".setFadeOutDuration", _fadeOutDuration / 1000.0)
EndFunction

Function UpdateMoveDuration()
	UI.InvokeFloat(HUD_MENU, WidgetRoot + ".setMoveDuration", _moveDuration / 1000.0)
EndFunction

Function UpdateRemoveDuration()
	UI.InvokeFloat(HUD_MENU, WidgetRoot + ".setRemoveDuration", _removeDuration)
EndFunction

Function AddActors(Form aForm)
	if ! aForm
		return
	endif
	AddActorRaw(aForm)
	if _currentlyDisplayedActors.find(aForm) < 0
		int i = _currentlyDisplayedActors.find(none)
		if i >= 0
			_currentlyDisplayedActors[i] = aForm
		endif
		;we do not have enough place in the array - the added actor will not be save game persistent
	endif
EndFunction

Function RemoveActors(Form aForm)
	if ! aForm
		return
	endif
	RemoveActorRaw(aForm)
	int i = _currentlyDisplayedActors.find(aForm)
	if i >= 0
		_currentlyDisplayedActors[i] = None
	Endif
EndFunction

Function AddActorRaw(Form aActor)
	UI.InvokeForm(HUD_MENU, WidgetRoot + ".addPanelActors", aActor)
EndFunction

Function RemoveActorRaw(Form aActor)
	UI.InvokeForm(HUD_MENU, WidgetRoot + ".removePanelActors", aActor)
EndFunction

GlobalVariable Property _00E_ActorHealthBarsEnabled Auto